Exportera cellområdesdata till textfil

Här visar hur vi relativt enkelt kan exportera ett cellområdes data till en textfil mha FileSystemObject.

För att exemplet ska fungera korrekt måste referens anges till  "Microsoft Scripting Runtime" - För närmare detaljer se Fil- och mapphantering.

Se också följande tips

 

Option Explicit

 Sub Exportera_Cellomrade_TextFil()

   '© 2002 Alla rättigheter XL-Dennis

   Dim fsoObject As Scripting.FileSystemObject

   Dim fsoFil As Object

   Dim rnCell As Range

   Dim vaFilnamn As Variant

   Dim lnRader As Long

 

   'Hämta filnamnet, från användarna, där cellområdets data ska sparas i.

   vaFilnamn = Application.GetSaveAsFilename("ExcelData.txt", _

                      "Text File (*.txt),*.txt,ASCII File (*.asc),*.asc", _

                      1, "Exportera cellområdets data till textfil")

   If vaFilnamn = False Then

      MsgBox "Du angav inget filnamn", vbInformation

      Exit Sub

   End If

 

   Set fsoObject = New Scripting.FileSystemObject

   Set fsoFil = fsoObject.CreateTextFile(vaFilnamn, True)

 

   lnRader = 0

    'Skriver cellområdets data till textfilen.

   For Each rnCell In Selection.Cells

      If rnCell.row <> lnRader Then

         If lnRader <> 0 Then

            fsoFil.Write Chr(13) & Chr(10)

         End If

         lnRader = rnCell.row

      End If

      fsoFil.Write rnCell.Value

      fsoFil.Write Chr(9)

   Next RnCell

 

   fsoFil.Close

   Set fsoObject = Nothing

End Sub