Läsa text från textfil till textbox
(FSO)


I detta exempel demonstreras hur vi mha av FSO-tekniken kan tilldela en textbox i ett formulär ett innehåll från textfiler.

För att exemplet ska fungera krävs att en referens till Microsoft Scipting Runtime anges - För mer information om det och om FSO se Fil- och mapphantering

Följande egenskaper hos Textbox-kontrollen ska tilldelas följande värden:

MultiLine: True

WordWrap: True
 

Om ett felmeddelande erhålls vid kopiering till VBA-modul så läs mer här»
 

 

(© 2002 - 2003 All rights Colo - Used by permission)

Option Explicit

 Private Sub cmbOk_Click()

   '© 2003 Alla rättigheter XL-Dennis

   Dim fsoObj As Scripting.FileSystemObject

   Dim fsoFile As Scripting.File

   Dim fsoTS As Scripting.TextStream

   Dim stFile As String, stText As String

 

   Set fsoObj = New FileSystemObject

 

   'Användaren får välja enhet, mapp och filnamn.

   With Application.FileDialog(msoFileDialogFilePicker)

      .Title = "Läsa in text från textfiler mha FSO"

      With .Filters

         .Clear

         .Add "Textfiler", "*.txt"

      End With

      .InitialFileName = ""

      'Om användaren avbryter.

      If .Show <> -1 Then

         Me.TextBox1.SetFocus

         Exit Sub

      End If

      stFile = .SelectedItems(1)

   End With

 

   'Öppnar den valda textfilen.

   Set fsoTS = fsoObj.OpenTextFile(stFile, ForReading, TristateFalse)

 

   'Här läses all text in.

   stText = fsoTS.ReadAll

 

   'Här tilldelas textbox den inlästa texten.

   With Me.TextBox1

      .SetFocus

      .Text = Replace(stText, """", "")

   End With

 

   Set fsoTS = Nothing

   Set fsoFile = Nothing

   Set fsoObj = Nothing

End Sub