Office-Assistenten1

Office-assistenten
Del 1

I detta tips tittar vi närmare på hur vi kan manipulera vissa egenskaper hos assistenten och även fånga upp vilka val användarna gör.

Koden kan kopieras och klistras in direkt i aktuella moduler eller så kan du hämta ett exempel här.

Se också Office-assistenten - Introduktion

Finns tillgänglig?

I det första exemplet visas ett sätt att hantera huruvida assistenten är tillgänglig och synlig eller ej. Om inte, så visas istället meddelandet i en meddelande-ruta.

Option Explicit

Sub Kontroll()
Visa_Meddelande "Assistenten synlig? ", "Är du där?"
End Sub

Function Visa_Meddelande(stRubrik As String, stText As String)
'© 2001 Alla rättigheter XL-Dennis
If Assistant.On And Assistant.Visible Then
        Dim obAssistent As Office.Balloon
        Set obAssistent = Assistant.NewBalloon

        With obAssistent
                .Heading = stRubrik
                .Text = stText
                .Button = msoButtonSetOK
                .Show
         End With
Else
       MsgBox Prompt:=stText, Buttons:=vbOKOnly, Title:=stRubrik
End If
End Function

Vilken knapp har valts?

Här demonstreras hur vi kan fånga upp vilken knapp användaren har använt.

Sub Vilken_Knapp()
'© 2001 Alla rättigheter XL-Dennis
Dim obAssistent As Office.Balloon
Dim lnKnapp As Long
Dim stTitel As String

stTitel = "Vald knapp"

Set obAssistent = Assistant.NewBalloon
With obAssistent
       .Heading = "Vilken knapp?"
       .Text = "Klicka på OK- eller Avbryt-knappen!"
       .Button = msoButtonSetOkCancel
       lnKnapp = .Show
End With

Select Case lnKnapp
       Case msoBalloonButtonOK
                MsgBox Prompt:="OK-knappen", Buttons:=vbOKOnly, Title:=stTitel
       Case msoBalloonButtonCancel
                MsgBox Prompt:="Avbryt-knappen", Buttons:=vbOKOnly, Title:=stTitel
End Select
End Sub

Vilket alternativ har valts?

Här visas hur vi kan kontrollera vilket alternativ som har valts.

Sub Valt_Alternativ()
'© 2001 Alla rättigheter XL-Dennis
Dim obAssistent As Office.Balloon

Set obAssistent = Assistant.NewBalloon
With obAssistent
       .Heading = "Alternativ"
       .Text = "Välj ett alternativ:"
       .Button = msoButtonSetOK
       .Icon = msoIconAlertInfo
       .CheckBoxes(1).Text = "Öppna budgetmallen"
       .CheckBoxes(2).Text = "Öppna resultatmallen"
       .Show
       If .CheckBoxes(1).Checked Then
             MsgBox "Öppnar budgetmallen..."
       ElseIf .CheckBoxes(2).Checked Then
             MsgBox "Öppnar resultatmallen..."
       Else
             MsgBox "Inget alternativ valt!"
       End If
End With
End Sub

Använda bildikoner!

För att liva upp livet med assistenten kan vi använda oss av bildikoner och där resultatet i exemplet blir följande assistent:

Sub Anvanda_BildIkoner()
'© 2001 Alla rättigheter XL-Dennis
Dim obAssistent As Office.Balloon
Dim stBildIkon1 As String, stBildIkon2 As String

stBildIkon1 = "{bmp c:\home.bmp}"
stBildIkon2 = "{bmp c:\xl.bmp}"

Set obAssistent = Assistant.NewBalloon
With obAssistent
        .Heading = "Ikoner"
        .Text = "Ytterligare sätt att infoga ikoner på:"
        .Button = msoButtonSetOK
        .Icon = msoIconAlertInfo
        .Labels(1).Text = "Gå hem " & stBildIkon1
        .Labels(2).Text = "Stäng XL " & stBildIkon2
        .Show
End With
End Sub

Textformatering

Vi kan också använda oss formatering för att förstärka text och göra assistenten roligare och där resultatet i exemplet blir följande färgglada assistent:

Sub TextFormatering()
'© 2001 Alla rättigheter XL-Dennis
Dim obAssistent As Office.Balloon

Set obAssistent = Assistant.NewBalloon
With obAssistent
       .Heading = "{cf 250} Grön text"
       .Text = "{cf 252} {ul} Litet mer färg {cf 249} {ul}med understrykning"
       .Button = msoButtonSetOK
       .Show
End With
End Sub

Office-assistenten Del 1

Office-assistenten
Del 1