Ta bort tomma rader och kolumner

Ta bort tomma rader & kolumner

Här demonstreras tekniker för att ta bort tomma rader och kolumner i ett markerat område.

I R-Verktyg ingår dylika verktyg, vilket du kan läsa mer om här.

Se också Ta bort rader med innehåll.

I det första exempel demonstreras hur vi tar bort tomma rader i en markering.

Sub Ta_Bort_Rader()
Dim iSistaRaden As Integer
Dim i As Integer
Dim j As Integer
Dim rnOmrade As Range

Application.ScreenUpdating = False
iSistaRaden = Selection.Rows.Count
Set rnOmrade = Selection

'Variabel som håller antalet borttagna rader nedan
j = 0

'Noterbart är att borttagning sker nedifrån och upp -
'därav en negativ stegräknare
For i = iSistaRaden To 1 Step -1
        If Application.CountA(rnOmrade.Rows(i)) = 0 Then
              rnOmrade.Rows(i).Delete
        j = j + 1
        End If
Next i

'Här justeras markeringen till att passa det nya markerade
'cellområdet.
rnOmrade.Resize(iSistaRaden - j).Select

Application.ScreenUpdating = True
End Sub

I nedanstående procedur demonstreras hur vi tar bort tomma kolumner i en markering.

Sub Ta_Bort_Kolumner()
Dim iSistaKolumnen As Integer
Dim i As Integer
Dim j As Integer
Dim rnOmrade As Range

Application.ScreenUpdating = False
iSistaKolumnen = Selection.Columns.Count
Set rnOmrade = Selection

j = 0

For i = iSistaKolumnen To 1 Step -1
        If Application.CountA(rnOmrade.Columns(i)) = 0 Then
              rnOmrade.Columns(i).Delete
              j = j + 1
        End If
Next i

'Notera komma-tecknet före variabeln ISistaKolumen
rnOmrade.Resize(, iSistaKolumnen - j).Select

Application.ScreenUpdating = False
End Sub